Olá seja bem vindo ao meu mais novo artigo
O método VIKOR - VIšeKriterijska Optimizacija Kompromisno Rješenje (Solução de compromisso de otimização multicritério) foi introduzido por Opricovic em 1998. Esta técnica é um dos métodos comprometedores em modelos compensatórios, pois o mais próximo alternativa para a solução ideal é preferida neste subgrupo. Geralmente, a técnica concentra-se na classificação de alternativas e na seleção de uma alternativa com um conjunto de atributos contraditórios e, em última análise, fornecem uma solução de compromisso, contribuindo o tomador de decisão para chegar à solução final. Esta técnica tem os seguintes recursos:
• É um dos métodos compensatórios;
• Os atributos devem ser independentes uns dos outros;
• Os atributos qualitativos devem ser convertidos em atributos quantitativos.
Neste artigo será demonstrado duas aplicações uma com o Lp-Metric outra sem o Lp-Metric.
Vamos ao método VIKOR passo a passo
VIKOR Sem o Lp-Metric
1° Etapa
Definição dos critérios de Maximização ou Minimização e seus pesos;
2° Etapa
Obter o máximo e o mínimo de cada critério
Segue a fórmula na célula C12 de Minimização
=SE(C$4="MIN";MÁXIMO(C6:C10);MÍNIMO(C6:C10))ou em inglês
=IF(C$4="MIN";MAX(C6:C10);MIN(C6:C10))Segue a fórmula na célula C13 de Maximização
=SE(C$4="MAX";MÁXIMO(C6:C10);MÍNIMO(C6:C10))ou em inglês
=IF(C$4="MAX";MAX(C6:C10);MIN(C6:C10))3° Etapa
Com os valores, deve obter os parâmetros S e R, para finalizar com o Critério Q. Neste exemplo foi utilizado o fato de 0,2 para a obtenção do ranking final
Segue o cálculo do parâmetro S, que segue na célula K6
=SOMA(ÍNDICE($C$3:$I$3*(($C$13:$I$13-C6:I6)/($C$13:$I$13-$C$12:$I$12));0))ou em inglês
=SUM(INDEX($C$3:$I$3*(($C$13:$I$13-C6:I6)/($C$13:$I$13-$C$12:$I$12));0))Segue o cálculo do parâmetro R, que segue na célula M6
=MÁXIMO(ÍNDICE($C$3:$I$3*(($C$13:$I$13-C6:I6)/
($C$13:$I$13-$C$12:$I$12));0))ou em inglês
=MAX(INDEX($C$3:$I$3*(($C$13:$I$13-C6:I6)/
($C$13:$I$13-$C$12:$I$12));0))Com os parâmetros S e R pode se obter o parâmetro Q, que segue na célula O6
=$O$4*((K6-MÍNIMO($K$6:$K$10))/(MÁXIMO($K$6:$K$10)-MÍNIMO($K$6:$K$10)))+(1-$O$4)*((M6-MÍNIMO($M$6:$M$10))/((MÁXIMO($M$6:$M$10)-MÍNIMO($M$6:$M$10))))ou em inglês
=$O$4*((K6-MIN($K$6:$K$10))/(MAX($K$6:$K$10)-MIN($K$6:$K$10)))+(1-$O$4)*((M6-MIN($M$6:$M$10))/((MAX($M$6:$M$10)-MIN($M$6:$M$10))))E segue a fórmula do Ranking final, iniciando na célula Q6
=SEERRO(ORDEM(O6;$O$6:$O$10);"")ou em inglês
=IFERROR(RANK(O6;$O$6:$O$10);"")Segue o método VIKOR dinâmico no Excel!
VIKOR com o Lp-Metric
1° Etapa
Definição dos critérios de Maximização ou Minimização e seus pesos;
2° Etapa
Criar a Matriz Normalizada
Segue a fórmula na célula C14
=C6/RAIZ(SOMAQUAD(C$6:C$10))ou em inglês
=C6/SQRT(SUMSQ(C$6:C$10))3° Etapa
Criar a Matriz de Obtenção dos Parâmetros, obter os parâmetros Si e Ri, para finalizar com o Critério Qi. Neste exemplo foi utilizado o fato de 0,5 para a obtenção do ranking final
Segue fórmula na célula C22
=SE(C$4="MAX";C$3*((MÁXIMO(C$14:C$18)-C14)/(MÁXIMO(C$14:C$18)-MÍNIMO(C$14:C$18)));C$3*((C14-MÍNIMO(C$14:C$18))/(MÁXIMO(C$14:C$18)-MÍNIMO(C$14:C$18))))ou em inglês
=IF(C$4="MAX";C$3*((MAX(C$14:C$18)-C14)/(MAX(C$14:C$18)-MIN(C$14:C$18)));C$3*((C14-MIN(C$14:C$18))/(MAX(C$14:C$18)-MIN(C$14:C$18))))Segue o cálculo do parâmetro Si, que segue na célula K22
=SOMA(C22:I22)ou em inglês
=SUM(C22:I22)Segue o cálculo do parâmetro R, que segue na célula M22
=MÁXIMO(C22:I22)ou em inglês
=MAX(C22:I22)Com os parâmetros S e R pode se obter o parâmetro Q, que segue na célula O6
=$O$20*((K22-MÍNIMO($K$22:$K$26))/(MÁXIMO($K$22:$K$26)-MÍNIMO($K$22:$K$26)))+(1-$O$20)*((M22-MÍNIMO($M$22:$M$26))/((MÁXIMO($M$22:$M$26)-MÍNIMO($M$22:$M$26))))ou em inglês
=$O$20*((K22-MIN($K$22:$K$26))/(MAX($K$22:$K$26)-MIN($K$22:$K$26)))+(1-$O$20)*((M22-MIN($M$22:$M$26))/((MAX($M$22:$M$26)-MIN($M$22:$M$26))))E segue a fórmula do Ranking final, iniciando na célula Q22
=SEERRO(ORDEM(O22;$O$22:$O$26);"")ou em inglês
=IFERROR(RANK(O22;$O$22:$O$26);"")Segue o método VIKOR dinâmico com a Lp-Metric no Excel!
Espero que tenha gostado desse artigo!
Segue o link abaixo para realizar o download do arquivo
O mesmo foi realizado o Registro de Software sob o Processo de Número BR512023003139-9, apenas para uso acadêmico e 100% gratuito e uso não comercial
Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.
Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.
Venha fazer o melhor curso EAD de Excel comigo! Clique e compare!
Abraços a todos e até o próximo artigo!
Fabio BALDINI
Frase do Dia: "Nossos fracassos, às vezes, são mais frutíferos do que os êxitos" Autor: Henry Ford
