▷ IDOCRIW no Excel – Integrated Determination of Objective Criteria Weights

Olá seja bem vindo ao meu mais novo artigo

O método IDOCRIW - Integrated Determination of Objective CRIteria Weights (Determinação Integrada de Pesos de Critérios Objetivos) foi introduzido por Zavadskas e Podvezko em 2016. Esta técnica se beneficia do método de Entropia e Impacto de Critério (CILOS) para determinar uma perda de impacto relativa, bem como o peso dos atributos em uma combinação com dois métodos. Além disso o método IDOCRIW possui as seguintes características:

• É um dos métodos compensatórios;
• Os atributos são independentes;
• Os atributos qualitativos devem ser convertidos em atributos quantitativos.

No exemplo abaixo será demonstrado uma aplicação com 4 critérios e 4 alternativas;

Vamos ao método IDOCRIW passo a passo;

1° Etapa

Definição dos critérios de Maximização ou Minimização;

2° Etapa

Criação da Matriz Normalizada e cálculo dos critérios d e Pesos(w) do IDOCRIW

Para a Matriz Normalizada, segue a fórmula na célula C12

=C5/SOMA(C$5:C$8)

ou em inglês

=C5/SUM(C$5:C$8)

Para o critério d, segue a fórmula inciando na célula C17

=1-(-1/LN($B$4)*(SOMA(ÍNDICE((C$12:C$15)*LN(C$12:C$15);0))))

ou em inglês

=1-(-1/LN($B$4)*(SUM(INDEX((C$12:C$15)*LN(C$12:C$15);0))))

Segue a fórmula dos Pesos (w) iniciando na Célula C18

=C17/SOMA($C$17:$F$17)

ou em inglês

=C17/SUM($C$17:$F$17)

3° Etapa

Deverá calcular os Valores Máximos da Matriz de Decisão e Normalizar.

Segue a fórmula da Matriz de Decisão dos Valores Máximos, iniciando a fórmula na célula C22

=SE(C$3="MIN";MÍNIMO(C$5:C$8)/C5;C5)

ou em inglês

=IF(C$3="MIN";MIN(C$5:C$8)/C5;C5)

Segue a fórmula da Matriz de Decisão Normalizada (r), iniciando a fórmula na célula C29

=C22/SOMA(C$22:C$25)

ou em inglês

=C22/SUM(C$22:C$25)

Para o cálculo do a-, segue na célula C34

=MÍNIMO(C29:C32)

ou em inglês

=MIN(C29:C32)

Para o cálculo do a-, segue na célula C35

=MÁXIMO(C29:C32)

ou em inglês

=MAX(C29:C32)

4° Etapa

Cálculo da Matriz A, nesta etapa é utilizado o método de CILOS (Entropy and Criterion Impact LOSs)

Nesta etapa que o entendimento dos artigos é bem confuso e complexo, mas vamos explicar o método:

Na diagonal principal deverá obter o máximo de cada coluna da Matriz R (Normalizada), e o restante dos valores terá que obter os valores restamtes por linha, no caso da Alternativa 1 e Critério 1 da Matriz a, o maior valor do Critério 1 (C1) é 0,319, por isso deve se utilizar todos os valores da linha da Alternativa 3 da Matriz R (Normalizada) para completar os valores na Alternativa 1 da Matriz a. Muito Obrigado Pablo Berriel pela grande ajuda no entendimento deste método! Obrigadão de coração!

5° Etapa

Cálculo dos maiores e menores valores da tabela A e Cálculo da Matriz p e wp para a obtenção dos pesos dos critérios

Para o cálculo do a- (mínimo) segue a fórmula na célula C43

=MÍNIMO(C38:C41)

ou em inglês

=MIN(C38:C41)

Para o cálculo do a+ (máximo) segue a fórmula na célula C44

=MÁXIMO(C38:C41)

ou em inglês

=MAX(C38:C41)

Para o cálculo da Matriz p, segue a fórmula na célula C47

=(MÁXIMO(C$38:C$41)-C38)/C$35

ou em inglês

=(MAX(C$38:C$41)-C38)/C$35

Para o cálculo da Matriz wp, segue a fórmula na célula C54

=SE(LINS($C$54:C54)=COLS($C$54:C54);-SOMA(C$47:C$50);C47)

ou em inglês

=IF(ROWS($C$54:C54)=COLUMNS($C$54:C54);-SUM(C$47:C$50);C47)

Nesta etapa será necessário a utilização do Solver para a obtenção dos coeficientes q1 a q4, para isso deve configurar conforme a imagem abaixo

Na célula I59, deve realizar a soma dos critérios q1 a q4, que segue a função abaixo

=SOMA(C59:F59)

ou em inglês

=SUM(C59:F59)

E na célula J54, deve realizar a multiplicação dos critérios e a soma, para isso segue a função abaixo

=SOMARPRODUTO(C54:F54;$C$59:$F$59)

ou em inglês

=SUMPRODUCT(C54:F54;$C$59:$F$59)

6° Etapa

Calculo dos pesos finais e Ranking dos critérios

Segue a fórmula do Peso final na célula C62

=C59*C18/SOMAPRODUTO($C$18:$F$18;$C$59:$F$59)

ou em inglês

=C59*C18/SUMPRODUCT($C$18:$F$18;$C$59:$F$59)

O Ranking final do Método IDOCRIW, segue a fórmula na célula C64

=ORDEM(C62;$C$62:$F$62)

ou em inglês

=RANK(C62;$C$62:$F$62)

Segue o método IDOCRIW Dinâmico!

Animated GIF - Find & Share on GIPHY

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Gostaria de fazer um agradecimento especial ao Eng. Pablo Berriel, pela grande ajuda para a construção deste método! Obrigadão de coração!

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

Venha fazer o melhor curso EAD de Excel comigo! Clique e compare!

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "O jeito mais eficiente de fazer algo é fazendo" Autor: Amelia Earhart

Deixe um comentário

O seu endereço de e-mail não será publicado.