▷ CRITIC no Excel – Criteria Importance Through Intercriteria Correlation

Olá seja bem vindo ao meu mais novo artigo

O método CRITIC - CRiteria Importance Through Intercriteria Correlation (Importância dos critérios através da correlação intercritérios), que foi proposto por Diakoulaki, Mavrotas e Papayannakis em 1995, é usado principalmente para determinar o peso dos atributos. No presente método, os atributos não estão em contradição uns com os outros e os pesos dos atributos são determinados usando a matriz de decisão. Além disso, o método CRITIC inclui as seguintes características:

• Não há necessidade de independência de atributos
• Os atributos qualitativos são transformados em atributos quantitativos.

No exemplo abaixo será demonstrado uma aplicação com 4 critérios e 4 alternativas;

Vamos ao método CRITIC passo a passo;

1° Etapa

Definição dos critérios de Maximização ou Minimização;

2° Etapa

Criar a Matriz Normalizada

Segue a fórmula iniciando na Célula C12

=SE(C$3="MAX";(C5-MÍNIMO(C$5:C$8))/(MÁXIMO(C$5:C$8)-MÍNIMO(C$5:C$8));(C5-MÁXIMO(C$5:C$8))/(MÍNIMO(C$5:C$8)-MÁXIMO(C$5:C$8)))

ou em inglês

=IF(C$3="MAX";(C5-MIN(C$5:C$8))/(MAX(C$5:C$8)-MIN(C$5:C$8));(C5-MAX(C$5:C$8))/(MIN(C$5:C$8)-MAX(C$5:C$8)))

3° Etapa

Criar a Matriz de Correlação entre os atributos de maneira dinâmica e ajustada do Método CRITIC

Segue a fórmula na célula C19

=1-SE($B19=C$18;1;CORREL(DESLOC($B$11;1;
CORRESP($B19;$C$11:$F$11;0);4;1);DESLOC(
$B$11;1;CORRESP(C$18;$C$11:$F$11;0);4;1)))

ou em inglês

=1-IF($B19=C$18;1;CORREL(OFFSET($B$11;1;
MATCH($B19;$C$11:$F$11;0);4;1);OFFSET(
$B$11;1;MATCH(C$18;$C$11:$F$11;0);4;1)))

Após a criação da Matriz de Correlação, deve realizar o cálculo do Atributo C, que segue na célula H19

=SOMA(C19:F19)*DESVPAD(DESLOC($B$11;1;CORRESP($B19;$C$11:$F$11;0);4;1))

ou em inglês

=SUM(C19:F19)*STDEV(OFFSET($B$11;1;MATCH($B19;$C$11:$F$11;0);4;1))

Com o critério C, é possível obter o peso de cada critério que segue na célula J19

=H19/SOMA($H$19:$H$22)

ou em inglês

=H19/SUM($H$19:$H$22)

O Ranking final do Método CRITIC, segue a fórmula na célula L19

=ORDEM(J19;$J$19:$J$22)

ou em inglês

=RANK(J19;$J$19:$J$22)

Segue o método CRITIC Dinâmico!

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

Venha fazer o melhor curso EAD de Excel comigo! Clique e compare!

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "Aquele que pensa positivo vê o invisível, sente o intangível e alcança o impossível" Autor: Winston Churchill

Deixe um comentário

O seu endereço de e-mail não será publicado. Campos obrigatórios são marcados com *