O Teste de Anderson-Darling no MS Excel (dinâmico)

Olá seja bem vindo ao meu mais novo artigo

O que é a estatística de Anderson-Darling?

Segue abaixo o artigo publicado dos autores (1952, 1954)

https://projecteuclid.org/download/pdf_1/euclid.aoms/1177729437

A estatística de Anderson-Darling mede se os dados seguem uma distribuição. Para um conjunto de dados e distribuição específico, quanto melhor a distribuição se ajustar aos dados, menor será a resposta estatística. Por exemplo, você pode usar a estatística de Anderson-Darling para determinar se os dados atendem à suposição de normalidade para um Teste t. As hipóteses para o teste Anderson-Darling são:

  • H0: Os dados seguem uma distribuição específica
  • H1: Os dados não seguem uma distribuição específica

O valor-p serve para testar se os dados correspondem a distribuição escolhida, neste artigo será utilizado a Distribuição Normal para a validação e testes dos resultados. Se o valor-p for menor que um alfa escolhido (geralmente 5% ou 10%), os dados não seguem a distribuição escolhida.

Também é possível usar a estatística de Anderson-Darling para comparar o ajuste de várias distribuições para determinar qual é o melhor. No entanto, a fim de concluir qual distribuição é a melhor, a estatística de Anderson-Darling deve ser substancialmente menor do que as outras.

Segue aos cálculos no MS Excel.

Será demonstrado em dois formatos o teste, a construção passo a passo do modelo e a construção de forma resumida e dinâmica para 1.000 amostras, em ambos os testes de Anderson-Darling foi considerado a Distribuição Normal.

1° Método - Construção passo a passo (Estático)

Segue os dados caso queira replicar este artigo

X
1,90642
2,10288
1,52229
2,61826
1,42738
2,22488
1,69742
3,15435
1,98492
1,99568

1° Passo - Classificar os dados do menor para o maior | Coluna C - C4:C13

=MENOR($B$4:$B$13;LINS($C$4:C4))

ou em inglês

=SMALL($B$4:$B$13;ROWS($C$4:C4))

2° Passo - Adicionar o Coeficiente | Coluna D - D4:D13

=2*LINS($D$4:D4)-1

ou em inglês

=2*ROWS($D$4:D4)-1

3° Passo - Calcular o Z | Coluna E - E4:E13

=(C4-$O$4)/$O$5

4° Passo - Classificar o Z do Maior para o Menor | Coluna F - F4:F13

=MAIOR($E$4:$E$13;LINS($F$4:F4))

ou em inglês

=LARGE($E$4:$E$13;ROWS($F$4:F4))

5° Passo - Adicionar a Função da Probabilidade da Distribuição Normal | Coluna G - G4:G13

=DIST.NORMP(E4)

ou em inglês

=NORMSDIST(E4)

6° Passo - Adicionar a Função da Probabilidade da Distribuição Normal | Coluna H - H4:H13

=DIST.NORMP(F4)

ou em inglês

=NORMSDIST(F4)

7° Passo - Adicionar a Função do Logaritmo Natural | Coluna I - I4:I13

=LN(G4)

8° Passo - Adicionar a Função Logaritmo Natural com Diminuição | Coluna J - J4:J13

=LN(1-H4)

9° Passo - Cálculo do Desvio Padrão de Anderson-Darling | Coluna I - K4:K13

=(1/$O$3)*D4*(I4+J4)

Após estes cálculos, precisaremos dos demais valores conforme abaixo

n-Número de amostras | Célula O3
=SOMA(ÍNDICE(--((B4:B13)<>"");0))

ou em inglês

=SUM(INDEX(--((B4:B13)<>"");0))

*Note que não foi utilizado a função do CONT.SE devido o alto consumo do processamento no MS Excel.

Média | Célula O4
=MÉDIA(B4:B13)

ou em inglês

=AVERAGE(B4:B13)
Desvio Padrão | Célula O5
=DESVPAD.A(B4:B13)

ou em inglês

=STDEV.S(B4:B13)
Desvio Padrão Anderson-Darling | Célula O6
=SOMA(K4:K13)

ou em inglês

=SUM(K4:K13)
Anderson-Darling Calculado | Célula O7
=-O3-O6

Anderson-Darling t | Célula P9

=SE($O$7<SE(O9=1%;1,029;SE(O9=2,5%;0,87;SE(O9=5%;0,751;SE(O9=10%;0,632;SE(O9=15%;0,56;"Erro")))));"É normal para "&TEXTO(O9;"0%");"Não é Normal")

ou em inglês

=IF($O$7<IF(O9=1%;1,029;IF(O9=2,5%;0,87;IF(O9=5%;0,751;IF(O9=10%;0,632;IF(O9=15%;0,56;"Erro")))));"É normal para "&TEXT(O9;"0%");"Não é Normal")

Anderson-Darling' | Célula O11

=O7*(1+0,75/$O$3+2,25/($O$3^2))

Valor-P | Célula O12

=SE(O11<0,2;1-EXP(-13,436+101,14*O11-223,73*O11^2);SE(O11<0,34;1-EXP(-8,318+42,796*O11-59,938*O11^2);SE(O11<0,6;EXP(0,9177-4,279*O11-1,38*O11^2);EXP(1,2937-5,709*O11+0,0186*O11^2))))

ou em inglês

=IF(O11<0,2;1-EXP(-13,436+101,14*O11-223,73*O11^2);IF(O11<0,34;1-EXP(-8,318+42,796*O11-59,938*O11^2);IF(O11<0,6;EXP(0,9177-4,279*O11-1,38*O11^2);EXP(1,2937-5,709*O11+0,0186*O11^2))))

Mensagem Final | Célula N14

=SE(O12<0,1;"Portanto, o p-valor é aproximadamente "&TEXTO(O12;"0,0%")&". Então, existe forte evidência de que os dados não provém de uma Distribuição Normal. ";"Então, existe forte evidência de que os dados provém de uma Distribuição Normal. ")

ou em inglês

=IF(O12<0,1;"Portanto, o p-valor é aproximadamente "&TEXT(O12;"0,0%")&". Então, existe forte evidência de que os dados não provém de uma Distribuição Normal. ";"Então, existe forte evidência de que os dados provém de uma Distribuição Normal. ")

Após demonstrado todo o passo a passo de modo "estático", é possível vincular este modelo ativando a ferramenta de Tabela do Excel, substituindo os intervalos pela coluna da Tabela de Dados do Excel.

2° Método - Construção Dinâmica (1.000 amostras)

Neste método é possível deixar somente a coluna de análise, caso queira aprender como reduzir as etapas do 1º método em uma única célula veja o vídeo abaixo

Segue abaixo as fórmulas compactadas

n-Número de amostras | Célula D5
=SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0))

ou em inglês

=SUM(INDEX(--(($A$6:$A$1006)<>"");0))

*Note que não foi utilizado a função do CONT.SE devido ao alto consumo do processamento no MS Excel.

Média | Célula D6
=MÉDIA((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))

ou em inglês

=AVERAGE((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))
Desvio Padrão | Célula D7
=DESVPAD.A((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))

ou em inglês

=STDEV.S((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))
Desvio Padrão Anderson-Darling | Célula D8
=SOMA(ÍNDICE((1/SOMA(ÍNDICE(--(((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))<>"");0)))*(2*LIN(INDIRETO("1:"&SOMA(ÍNDICE(--(((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))<>"");0))))-1)*(LN(DIST.NORMP(((MENOR((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1));LIN(INDIRETO("1:"&SOMA(ÍNDICE(--(((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))<>"");0))))))-MÉDIA((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))))/DESVPAD.A((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))))+LN(1-DIST.NORMP(MAIOR(((ÍNDICE(MENOR((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1));LIN(INDIRETO("1:"&SOMA(ÍNDICE(--(((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))<>"");0)))));0))-MÉDIA((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))))/DESVPAD.A((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)));LIN(INDIRETO("1:"&SOMA(ÍNDICE(--(((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))<>"");0))))))));0))

ou em inglês

=SUM(INDEX((1/SUM(INDEX(--(((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))<>"");0)))*(2*ROW(INDIRECT("1:"&SUM(INDEX(--(((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))<>"");0))))-1)*(LN(NORMSDIST(((SMALL((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1));ROW(INDIRECT("1:"&SUM(INDEX(--(((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))<>"");0))))))-AVERAGE((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))))/STDEV.S((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))))+LN(1-NORMSDIST(LARGE(((INDEX(SMALL((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1));ROW(INDIRECT("1:"&SUM(INDEX(--(((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))<>"");0)))));0))-AVERAGE((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))))/STDEV.S((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)));ROW(INDIRECT("1:"&SUM(INDEX(--(((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))<>"");0))))))));0))
Anderson-Darling Calculado | Célula D9
=-SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))-SOMA(ÍNDICE((1/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0)))*(2*LIN(INDIRETO("1:"&SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))))-1)*(LN(DIST.NORMP(((MENOR(DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1);LIN(INDIRETO("1:"&SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))))))-MÉDIA(DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))/DESVPAD.A(DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))))+LN(1-DIST.NORMP(MAIOR(((ÍNDICE(MENOR(DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1);LIN(INDIRETO("1:"&SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0)))));0))-MÉDIA(DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1)))/DESVPAD.A(DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1));LIN(INDIRETO("1:"&SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))))))));0))

Ou em inglês

=-SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))-SUM(INDEX((1/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0)))*(2*ROW(INDIRECT("1:"&SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))))-1)*(LN(NORMSDIST(((SMALL(OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1);ROW(INDIRECT("1:"&SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))))))-AVERAGE(OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))/STDEV.S(OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))))+LN(1-NORMSDIST(LARGE(((INDEX(SMALL(OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1);ROW(INDIRECT("1:"&SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0)))));0))-AVERAGE(OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1)))/STDEV.S(OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1));ROW(INDIRECT("1:"&SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))))))));0))

Anderson-Darling t | Célula F11

=SE($D$9<SE(D11=1%;1,029;SE(D11=2,5%;0,87;SE(D11=5%;0,751;SE(D11=10%;0,632;SE(D11=15%;0,56;"Erro")))));"É normal para "&TEXTO(D11;"0%");"Não é Normal")

ou em inglês

=IF($D$9<IF(D11=1%;1,029;IF(D11=2,5%;0,87;IF(D11=5%;0,751;IF(D11=10%;0,632;IF(D11=15%;0,56;"Erro")))));"É normal para "&TEXT(D11;"0%");"Não é Normal")

Valor-P | Célula D13

=SE((D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))<0,2;1-EXP(-13,436+101,14*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))-223,73*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2);SE((D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))<0,34;1-EXP(-8,318+42,796*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))-59,938*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2);SE((D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))<0,6;EXP(0,9177-4,279*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))-1,38*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2);EXP(1,2937-5,709*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((ÍNDICE(A6;0):DESLOC(A6;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0))-1;0))<>"");0))^2)))+0,0186*(D9*(1+0,75/SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SOMA(ÍNDICE(--((DESLOC(A6;0;0;SOMA(ÍNDICE(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2))))

ou em inglês

=IF((D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))<0,2;1-EXP(-13,436+101,14*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))-223,73*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2);IF((D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))<0,34;1-EXP(-8,318+42,796*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))-59,938*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2);IF((D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))<0,6;EXP(0,9177-4,279*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))-1,38*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2);EXP(1,2937-5,709*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((INDEX(A6;0):OFFSET(A6;SUM(INDEX(--(($A$6:$A$1006)<>"");0))-1;0))<>"");0))^2)))+0,0186*(D9*(1+0,75/SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))+2,25/(SUM(INDEX(--((OFFSET(A6;0;0;SUM(INDEX(--(($A$6:$A$1006)<>"");0));1))<>"");0))^2)))^2))))

Mensagem Final | Célula C15

=SE(D13<0,1;"Portanto, o p-valor é aproximadamente "&TEXTO(D13;"0,0%")&". Então, existe forte evidência de que os dados não provém de uma distribuição Normal. ";"Então, existe forte evidência de que os dados provém de uma distribuição Normal. ")

ou em inglês

=IF(D13<0,1;"Portanto, o p-valor é aproximadamente "&TEXT(D13;"0,0%")&". Então, existe forte evidência de que os dados não provém de uma distribuição Normal. ";"Então, existe forte evidência de que os dados provém de uma distribuição Normal. ")

Após demonstrado todo o passo a passo de modo "dinâmico", é possível vincular este modelo ativando a ferramenta de Tabela do Excel, substituindo os intervalos pela coluna da Tabela do MS Excel.

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

E já se inscreveu no meu mais novo Canal do Youtube?

https://www.Youtube.com/InstitutoX

Não se esqueça de ativar o sininho para receber sempre as notificações do Instituto X.

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "Uma mudança sempre deixa o caminho aberto para outras" Autor: Nicolau Maquiavel

Deixe uma resposta

O seu endereço de e-mail não será publicado. Campos obrigatórios são marcados com *