▷ MULTIMOORA no Excel – MOORA Plus Full Multiplicative

Olá seja bem vindo ao meu mais novo artigo

O método MULTIMOORA - Multi-Objective Optimization on the basis of Ratio Analisys Multiplicative Form (Otimização Multi-Objetivo com base no Formulário Multiplicativo de Análise de Razão), foi introduzida por Willem Karel Brauers e Edmund Kazimieras Zavadskas em 2010, visa otimizar simultaneamente duas ou mais qualidades ou objetivos sobrepostos sob restrições. Sendo necessário dar maior importância a alguma resposta de um objetivo com base em uma alternativa escolhida, se pode multiplicar o valor de desempenho de acordo com os critérios relacionados por um coeficiente de significância dentro do processo de ambos.

• Pertence aos métodos compensatórios;
• Os atributos são independentes;
• Os atributos qualitativos são convertidos em atributos quantitativos;
• Não linear, Não Aditiva e não utiliza de pesos em seus atributos.

Segue o artigo com a referência citada do método MULTIMOORA

https://www.researchgate.net/publication/228470153

Mas antes queria agradecer a imensa ajuda no entendimento do passo a passo deste método da Eng.a Natália O. B. de Paula, muito obrigado de coração!

No exemplo abaixo será demonstrado a aplicação do artigo com 7 critérios e 6 alternativas;

Vamos ao método MULTIMOORA passo a passo;

1° Etapa

Definição dos critérios de Maximização ou Minimização;

2° Etapa

Criação da Matriz Normalizada Método MULTIMOORA (MOORA)

Segue a fórmula na célula C14

=C5/RAIZ(SOMAQUAD(C$5:C$10))

ou em inglês

=C5/SQRT(SUMSQ(C$5:C$10))

Cálculo de S(x), segue a fórmula inciando na célula K14

=SOMASE($C$3:$I$3;"MAX";C14:I14)-SOMASE($C$3:$I$3;"MIN";C14:I14)

ou em inglês

=SUMIF($C$3:$I$3;"MAX";C14:I14)-SUMIF($C$3:$I$3;"MIN";C14:I14)

O Ranking do Método MOORA, segue a fórmula na célula M14

=ORDEM(K14;$K$14:$K$19)

ou em inglês

=RANK(K14;$K$14:$K$19)

3° Etapa

Criação da Matriz de Tchebytcheff - Ponto de Referência

Segue a fórmula iniciada na célula C23

=SE(C$3="MIN";MÍNIMO(C$14:C$19);MÁXIMO(C$14:C$19))-C14

ou em inglês

=IF(C$3="MIN";MIN(C$14:C$19);MAX(C$14:C$19))-C14

Para o resultado do Máximo, segue a fórmula iniciando na célula K23

=MÁXIMO(C23:I23)

ou em inglês

=MAX(C23:I23)

O Ranking do Método Tchebytcheff, que segue na célula M23

=ORDEM(K23;$K$23:$K$28;1)

ou em inglês

=RANK(K23;$K$23:$K$28;1)

4° Etapa

Criação da Matriz de Correção Multiplicativa do Método MULTIMOORA

Nesta etapa foi otimizado para a criação da Matriz de Correção Multiplicativa, que segue a fórmula iniciando na célula D32

=SE(C32="";SE(D$3="MIN";C5/D5;C5*D5);SE(D$3="MIN";C32/D5;C32*D5))

ou em inglês

=IF(C32="";IF(D$3="MIN";C5/D5;C5*D5);IF(D$3="MIN";C32/D5;C32*D5))

Para o Cálculo do S(x) final segue na célula K32

=SOMASE($C$3:$I$3;"MAX";C32:I32)-SOMASE($C$3:$I$3;"MIN";C32:I32) +SOMASE($C$3:$I$3;"MAX";C5:I5)-SOMASE($C$3:$I$3;"MIN";C5:I5)

ou em inglês

=SUMIF($C$3:$I$3;"MAX";C32:I32)-SUMIF($C$3:$I$3;"MIN";C32:I32) +SUMIF($C$3:$I$3;"MAX";C5:I5)-SUMIF($C$3:$I$3;"MIN";C5:I5)

E o Raking Final que segue na célula M32

=ORDEM(K32;$K$32:$K$37)

ou em inglês

=RANK(K32;$K$32:$K$37)

Segue o método MULTIMOORA Dinâmico!

Espero que tenha gostado desse artigo!

Novamente gostaria agradecer imensamente ajuda da Eng.a Natália O. B. de Paula para este método, muito obrigado de coração!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

Venha fazer o melhor curso EAD de Excel comigo! Clique e compare!

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "Você precisa fazer aquilo que pensa que não é capaz de fazer." Autor: Eleanor Roosevelt

Deixe um comentário

O seu endereço de e-mail não será publicado. Campos obrigatórios são marcados com *