▷ EVAMIX no Excel – Evaluation of Mixed

Olá seja bem vindo ao meu mais novo artigo

O método EVAluation of MIXed data (EVAMIX), introduzido em 1982 por Voogd, com duas abordagens completamente diferentes para atributos quantitativo, qualitativo e independentes. Portanto, EVAMIX ajuda especialistas e gestores a chegarem rapidamente à solução, devido à sua insensibilidade em conversão de atributos qualitativos em atributos quantitativos. Este método possuem as seguintes características:

• É um dos métodos compensatórios;
• Os atributos são independentes uns dos outros;
• Não é necessário converter os atributos qualitativos em quantitativos
atributos.

No exemplo abaixo será demonstrado uma aplicação com 6 critérios e 3 alternativas,

Vamos ao método EVAMIX passo a passo

1° Etapa

Definir os Pesos de cada critério e se o critério é de Maximização ou Minimização

2° Etapa

Nesta etapa deverá separar os critérios qualitativos (ordinais) e quantitativos (cardinais)

3° Etapa

Após a separação, deverá realizar os cálculos de conversão dos critérios Qualitativos com a matriz auxiliar,

Segue o cálculo de conversão dos valores para números considerando a maximização e minimização de cada critério iniciando na célula M21

=PROCV(M15;$Q$20:$S$23;SE(M$13=$R$19;2;3);0)

ou em inglês

=VLOOKUP(M15;$Q$20:$S$23;IF(M$13=$R$19;2;3);0)

Após a conversão, deverá fazer a comparação entre as alternativas, que segue a fórmula iniciando na célula M26

=SE(ÍNDICE(M$21:M$23;CORRESP($K26;$L$21:$L$23;0))>ÍNDICE(M$21:M$23;CORRESP($L26;$L$21:$L$23;0));-1;1)

ou em inglês

=IF(INDEX(M$21:M$23;MATCH($K26;$L$21:$L$23;0))>INDEX(M$21:M$23;MATCH($L26;$L$21:$L$23;0));-1;1)

Após os valores deverá calcular o α

=SOMARPRODUTO(M26:O26;$M$12:$O$12)

ou em inglês

=SUMPRODUCT(M26:O26;$M$12:$O$12)

Com o α por alternativa, deve calcular a Matriz de Superioridade entre as Alternativas, que segue a fórmula iniciando na célula M32

=SOMASES($P$26:$P$28;$K$26:$K$28;$L32;$L$26:$L$28;M$31)-SOMASES($P$26:$P$28;$K$26:$K$28;M$31;$L$26:$L$28;$L32)

ou em inglês

=SUMIFS($P$26:$P$28;$K$26:$K$28;$L32;$L$26:$L$28;M$31)-SUMIFS($P$26:$P$28;$K$26:$K$28;M$31;$L$26:$L$28;$L32)

Segue a fórmula do cálculo da Matriz Diferencial dos atributos ordinais, iniciando na célula M38

=(M32-MÍNIMO($M$32:$O$34))/(MÁXIMO($M$32:$O$34)-MÍNIMO($M$32:$O$34))

ou em inglês

=(M32-MIN($M$32:$O$34))/(MAX($M$32:$O$34)-MIN($M$32:$O$34))

4° Etapa

Segue os cálculos dos critérios quantitativos (cardinais)

Nesta etapa deveremos calcular o α cardinal que segue a fórmula iniciando na célula E26

=SOMA(ÍNDICE(((DESLOC($D$14;CORRESP(C26;$D$15:$D$17;0);1;1;3)-DESLOC($D$14;CORRESP(D26;$D$15:$D$17;0);1;1;3))*($E$13:$G$13="MAX")+(DESLOC($D$14;CORRESP(C26;$D$15:$D$17;0);1;1;3)-DESLOC($D$14;CORRESP(D26;$D$15:$D$17;0);1;1;3))*($E$13:$G$13="MIN")*-1)*($E$12:$G$12);0))

ou em inglês

=SUM(INDEX(((OFFSET($D$14;MATCH(C26;$D$15:$D$17;0);1;1;3)-OFFSET($D$14;MATCH(D26;$D$15:$D$17;0);1;1;3))*($E$13:$G$13="MAX")+(OFFSET($D$14;MATCH(C26;$D$15:$D$17;0);1;1;3)-OFFSET($D$14;MATCH(D26;$D$15:$D$17;0);1;1;3))*($E$13:$G$13="MIN")*-1)*($E$12:$G$12);0))

Com o α cardinal calculado, deve calcular a Matriz de Superioridade entre as alternativas iniciando na célula E32

=SOMASES($E$26:$E$28;$C$26:$C$28;$D32;$D$26:$D$28;E$31)-SOMASES($E$26:$E$28;$C$26:$C$28;E$31;$D$26:$D$28;$D32)

ou em inglês

=SUMIFS($E$26:$E$28;$C$26:$C$28;$D32;$D$26:$D$28;E$31)-SUMIFS($E$26:$E$28;$C$26:$C$28;E$31;$D$26:$D$28;$D32)

Segue a fórmula do cálculo da Matriz Diferencial dos atributos cardinais, iniciando na célula E38

=(E32-MÍNIMO($E$32:$G$34))/(MÁXIMO($E$32:$G$34)-MÍNIMO($E$32:$G$34))

ou em inglês

=(E32-MIN($E$32:$G$34))/(MAX($E$32:$G$34)-MIN($E$32:$G$34))

4° Etapa

Com as Matrizes Diferenciais Ordinais e Cardinais deverá fazer a Matriz de Dominância Final, que segue abaixo:

Segue a fórmula na célula L49

=$Q$12*M38+$I$12*E38

Para o cálculo do critério Si (classificação final das alternativas) segue abaixo iniciando na célula O49* (caso você tenha uma versão abaixo do Excel 365/2019 deverá apertar o Control+Shift+Enter para funcionar)

=SOMA(SEERRO(TRANSPOR(DESLOC($K$43;1;CORRESP($K44;$L$43:$N$43;0);3;1))/L44:N44;0))^-1

ou em inglês

=SUM(IFERROR(TRANSPOSE(OFFSET($K$48;1;MATCH($K49;$L$48:$N$48;0);3;1))/L49:N49;0))^-1

E segue a fórmula do Ranking final, iniciando na célula P49

=SEERRO(ORDEM(O44;$O$44:$O$46);"")

ou em inglês

=IFERROR(RANK(O49;$O$49:$O$51);"")

Segue o método EVAMIX dinâmico no Excel!

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

Venha fazer o melhor curso EAD de Excel comigo! Clique e compare!

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "As teorias são redes: somente aqueles que as lançam pescarão alguma coisa" Autor: Noralis (cit Rubem Alves)