▷ Taxonomy no Excel

Olá seja bem vindo ao meu mais novo artigo

O método de Taxonomy foi introduzido por Adanson em 1763 e expandido por um grupo de matemáticos da Polônia em 1950. Em 1968, Zyegnant Hellwing da escola secundária de Wroclaw introduziu este método como um meio de classificar e determinar o grau de desenvolvimento. Este método é muito apropriado para graduar, classificar e comparar diferentes atividades quanto às suas vantagens e grau de utilidade dos atributos estudados. O método Taxonomy possui os seguintes recursos:

• É um dos métodos compensatórios;
• Os atributos qualitativos são convertidos em atributos quantitativos;
• Os atributos são independentes.

No exemplo abaixo será demonstrado uma aplicação com 3 critérios e 3 alternativas;

Vamos ao método Taxonomy passo a passo;

1° Etapa

Definição dos critérios de Maximização ou Minimização;

2° Etapa

Criação da Matriz Padronizada do Método Taxonomy

Segue a fórmula na célula C11

=(C5-MÉDIA(C$5:C$7))/DESVPAD(C$5:C$7)

ou em inglês

=(C5-AVERAGE(C$5:C$7))/STDEV(C$5:C$7)

3° Etapa

Criação da Matriz das Distâncias Compostas e Fator Z

Segue a fórmula inciando na célula C17

=RAIZ(SOMA(ÍNDICE((DESLOC($B$10;CORRESP($B17;$B$11:$B$13;0);1;1;3)-DESLOC($B$10;CORRESP(C$16;$B$11:$B$13;0);1;1;3))^2;0)))

ou em inglês

=SQRT(SUM(INDEX((OFFSET($B$10;MATCH($B17;$B$11:$B$13;0);1;1;3)-OFFSET($B$10;MATCH(C$16;$B$11:$B$13;0);1;1;3))^2;0)))

Fator Zo, segue a fórmula inciando na célula C21

=SE(C3="MIN";MÍNIMO(C11:C13);MÁXIMO(C11:C13))

ou em inglês

=IF(C3="MIN";MIN(C11:C13);MAX(C11:C13))

4° Etapa

Calcular todos as etapas de Homogeniedade, caso aceito, deverá realizar os cálculos de Co e F e consequentemente o Ranking final

Fator O, segue a fórmula inciando na célula G17

=MÍNIMOSES(C17:E17;C17:E17;">0")

ou em inglês

=MINIFS(C17:E17;C17:E17;">0")

Média, segue a fórmula na célula J16

=MÉDIA(G17:G19)

ou em inglês

=AVERAGE(G17:G19)

Desvio Padrão, segue a fórmula na célula J17

=DESVPAD(G17:G19)

ou em inglês

=STDEV(G17:G19)

Fator H, Segue a fórmula nas celulas J19 e L19

=J16+J17*2 | =J16-J19

Validação do teste de homogeniedade, que segue a fórmula na célula N17

=SE(E(G17<$J$19;G17>$L$19);"Aceito";"Eliminar")

ou em inglês

=IF(AND(G17<$J$19;G17>$L$19);"Aceito";"Eliminar")

Cálculo do Co (limte superior)

=RAIZ(SOMA(ÍNDICE((C11:E11-$C$21:$E$21)^2;0)))

ou em inglês

=SQRT(SUM(INDEX((C11:E11-$C$21:$E$21)^2;0)))

Cálculo do F (Valor do atributo)

=P17/(MÉDIA($P$17:$P$19)+2*DESVPAD($P$17:$P$19))

ou em inglês

=P17/(AVERAGE($P$17:$P$19)+2*STDEV($P$17:$P$19))

O Ranking final do Método Taxonomy, segue a fórmula na célula T13

=ORDEM(R17;$R$17:$R$19;1)

ou em inglês

=RANK(R17;$R$17:$R$19;1)

Segue o método Taxonomy Dinâmico!

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

Venha fazer o melhor curso EAD de Excel comigo! Clique e compare!

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "Conhecimento não é aquilo que você sabe, mas o que você faz com aquilo que sabe" Autor: Aldous Huxley

1 comentário

Deixe um comentário

O seu endereço de e-mail não será publicado.