▷ Decisão Tomada sob Risco (DTSR) no Excel

Olá seja bem vindo ao meu mais novo artigo

Neste irei descrever duas técnicas que irá te subsidiar na tomada de decisão sob Risco.

Gostaria de agradecer novamente ao Prof. Dr. Marcos Santos por disponibilizar este material para compor este artigo, muito obrigado Professor e ao Mestre Thiago Marques por disponibilizar em seu canal do Youtube.

Segue o video onde é demonstrado passo a passo e toda a explicação teórica

Mas vamos para o Excel

Nesta aplicação temos a seguinte situação, ou compramos de um terceirizado ou produzimos internamente. Mas temos as três alternativas de Demanda, Baixa, Média ou Alta e com suas respectivas chances de acontecer.

Caso a Demanda for Baixa (40% de chance de acontecer)

Teremos o custo de R$ 10 e se formos manufaturar o produto teremos os custos internos de R$-30 (pagaremos para trabalhar)

Caso a Demanda for Média (35% de chance de acontecer)

Teremos o custo de R$ 40 e se formos manufaturar o produto teremos os custos internos de R$20

Caso a Demanda for Alta (25% de chance de acontecer)

Teremos o custo de R$ 100 e se formos manufaturar o produto teremos os custos internos de R$150

A questão é, qual é a melhor alternativa para tomar com base nestes riscos.

Para isso temos que listar quantas linhas (alternativas) e colunas (chances)

Fórmula da quantidade de Colunas (chances), célula C13

=CONT.NÚM(G3:AAA3)

ou em inglês

=COUNT(G3:AAA3)

Fórmula da quantidade de Linhas (alternativas), célula C14

=CONT.VALORES(F5:F505)

ou em inglês

=COUNTA(F5:F505)

Para nos suportar nesta tomada de decisão, isso existe duas técnicas, são elas

1° Método - Máxima Verossimilhança

Neste critério é utilizado o máximo da probabilidade de chance que ocorra e do intervalo de alternativas é escolhido a alternativa com o maior valor.

Segue a fórmula do valor máximo, célula C6

=MÁXIMO(DESLOC($F$3;2;CORRESP(MÁXIMO($3:$3);$3:$3;0)-COL($F$3);C14;1))

ou em inglês

=MAX(OFFSET($F$3;2;MATCH(MAX($3:$3);$3:$3;0)-COLUMN($F$3);C14;1))

Segue a fórmula do nome da alternativa do valor máximo, célula C5

=ÍNDICE($F:$F;CORRESP(MÁXIMO(DESLOC($F$3;2;CORRESP(MÁXIMO($3:$3);$3:$3;0)-COL($F$3);C14;1));DESLOC($F$3;2;CORRESP(MÁXIMO($3:$3);$3:$3;0)-COL($F$3);C14;1);0)+LIN($F$3)+1;0)

ou em inglês

=@INDEX($F:$F;MATCH(MAX(OFFSET($F$3;2;MATCH(MAX($3:$3);$3:$3;0)-COLUMN($F$3);C14;1));OFFSET($F$3;2;MATCH(MAX($3:$3);$3:$3;0)-COLUMN($F$3);C14;1);0)+ROW($F$3)+1;0)

2° Método - Regra de Bayes

Este método consiste em realizar a soma dos produtos (entre valores e chances) e obter o maior valor desta combinação.

Segue a fórmula do valor máximo da soma dos produtos, célula C11

=MÁXIMO(MATRIZ.MULT(DESLOC($F$4;1;1;$C$14;$C$13)*DESLOC($F$3;0;1;1;$C$13);LIN(INDIRETO("1:"&$C$13))/LIN(INDIRETO("1:"&$C$13))))

ou em inglês

=MAX(MMULT(OFFSET($F$4;1;1;$C$14;$C$13)*OFFSET($F$3;0;1;1;$C$13);ROW(INDIRECT("1:"&$C$13))/ROW(INDIRECT("1:"&$C$13))))

Segue a fórmula do nome da alternativa do valor máximo da soma dos produtos, célula C10

=ÍNDICE($F:$F;LIN($F$4)+CORRESP(MÁXIMO(MATRIZ.MULT(DESLOC($F$4;1;1;$C$14;$C$13)*DESLOC($F$3;0;1;1;$C$13);LIN(INDIRETO("1:"&$C$13))/LIN(INDIRETO("1:"&$C$13))));MATRIZ.MULT(DESLOC($F$4;1;1;$C$14;$C$13)*DESLOC($F$3;0;1;1;$C$13);LIN(INDIRETO("1:"&$C$13))/LIN(INDIRETO("1:"&$C$13)));0);0)

ou em inglês

=@INDEX($F:$F;ROW($F$4)+MATCH(MAX(MMULT(OFFSET($F$4;1;1;$C$14;$C$13)*OFFSET($F$3;0;1;1;$C$13);ROW(INDIRECT("1:"&$C$13))/ROW(INDIRECT("1:"&$C$13))));MMULT(OFFSET($F$4;1;1;$C$14;$C$13)*OFFSET($F$3;0;1;1;$C$13);ROW(INDIRECT("1:"&$C$13))/ROW(INDIRECT("1:"&$C$13)));0);0)

Segue as Técnicas de Tomada de Decisão sob Risco de maneira dinâmica