▷ Decisão Tomada sob Incerteza (DTSI) no Excel

Olá seja bem vindo ao meu mais novo artigo

Neste será descrito uma combinação de técnicas para subsidiar a tomada de decisão sob incerteza.

Antes de iniciar quero agradecer imensamente ao Prof. Dr. Marcos Santos por disponibilizar este material tão rico, segue a live do Professor abaixo.

Mas vamos para o Excel

Temos a seguinte situação

Sendo o MF: Muito Favorável | F: Favorável | M: Médio | A: Aceito | MA: Muito Aceito | A: Acima da média | H: Highlevel | U: Utralevel

E precisamos decidir qual ação temos que realizar com as alternativas apresentadas. Para este problema vamos verificar 6 técnicas que irá nos orientar a qual melhor decisão a ser tomada. Vamos aos métodos.

1° Método - Maximax

Este método deve escolher o melhor resultado de cada alternativa e, em seguida, escolher o melhor dos melhores. Segue a fórmula na coluna B, iniciando na célula B8.

=SE(J8="";"";MÁXIMO(DESLOC(K8;0;0;1;$G$2)))

ou em inglês

=IF(J8="";"";MAX(OFFSET(K8;0;0;1;$G$2)))

2° Método - Maximin (Wald)

Este método deve escolher o "máximo entre os mínimos". Para cada alternativa, escolhe-se o pior resultado, dentre os piores, escolhe-se o melhor resultado, ou o "menos pior". Segue a fórmula na coluna C, iniciando na célula C8 .

=SE(J8="";"";MÍNIMO(DESLOC(K8;0;0;1;$G$2)))

ou em inglês

=IF(J8="";"";MIN(OFFSET(K8;0;0;1;$G$2)))

3° Método - Laplace ou critério da razão insuficiente

Este método deve escolher a melhor "média dos valores". Pois assume que são idênticas as probabilidades dos diversos estados da natureza. Segue a fórmula na coluna D, iniciando na célula D8.

=SE(J8="";"";MÉDIA(DESLOC(K8;0;0;1;$G$2)))

ou em inglês

=IF(J8="";"";AVERAGE(OFFSET(K8;0;0;1;$G$2)))

4° Método - Média Variabilidade

Este método combina a média, o pior e o melhor resultado. Deverá obter a média dos valores e dividir pela diferença entre o maior e o menor valor. Este método se caracteriza pela variabilidade dos resultados além da própria média. Segue a fórmula na coluna E, iniciando na célula E8.

=SE(J8="";"";D8/(B8-C8))

ou em inglês

=IF(J8="";"";D8/(B8-C8))

5° Método - Hurwicz ou critério do realismo ou média ponderada

Criado por Leonid Hurwicz (1917-2008), para este método é adicionado uma variável α (alfa) chamado de coeficiente de realismo, variando entre 0 e 1. Quanto maior o valor de alfa, mais otimista o tomador de decisão está em relação ao futuro. Segue a fórmula na coluna G, iniciando na célula G8

=SE($J8="";"";$B8*$G$4+$C8*(1-$G$4))

ou em inglês

=IF(J8="";"";B8*$G$4+C8*(1-$G$4))

6° Método - Mínimo Arrependimento ou critério de Savage

Para este método será necessário criar uma matriz de arrependimento, vamos a ela

Inicialmente é necessário obter o maior valor de cada estado, que se encontra na linha 6

Segue a fórmula para obtenção do maior valor por estado, iniciando na célula K6

=SE(K7="";"";MÁXIMO(DESLOC(K$7;1;0;$G$3;1)))

ou em inglês

=IF(K7="";"";MAX(OFFSET(K$7;1;0;$G$3;1)))

Para a criação da matriz de arrependimento, deverá obter o valor máximo e subtrair por cada valor da matriz por coluna (em cada estado), resultando na tabela abaixo.

OBS: a fórmula que irei propor não será necessário a criação desta matriz de arrependimento, somente da linha onde contém os valores máximos por estado (coluna)

Para a obtenção do valor por alternativa segue a fórmula na coluna F, iniciando na célula F8;

=SE(J8="";"";MÁXIMO(ÍNDICE(DESLOC($K$6;0;0;1;$G$2)-DESLOC(K8;0;0;1;$G$2);0)))

ou em inglês

=IF(J8="";"";MAX(INDEX(OFFSET($K$6;0;0;1;$G$2)-OFFSET(K8;0;0;1;$G$2);0)))

Neste momento já temos todos os valores dos seis métodos e será necessário calcular os valores da linha 6, sendo os valores máximos e mínimos, vamos a eles.

Todos os métodos exceto o 6° (mínimo arrependimento) deverá se obter o maior valor e segue abaixo a fórmula que deverá ser aplicada nas células B6 até a E6 e G6

=MÁXIMO(DESLOC(B$7;1;0;$G$3;1))

ou em inglês

=MAX(OFFSET(B$7;1;0;$G$3;1))

Somente no 6° método que deve ser utilizado o menor valor, segue a fórmula abaixo aplicada na célula F6

=MÍNIMO(DESLOC(F$7;1;0;$G$3;1))

ou em inglês

=MIN(OFFSET(F$7;1;0;$G$3;1))

Com todos os dados já em calculados, a melhor escolha será que tiver a maior número de alternativas conforme a imagem abaixo

Sendo que a alternativa "Vender" obteve dois critérios como o melhor e portanto é a melhor escolha a se tomar.

Segue o modelo DTSI - Decisão Tomada sob Incerteza de maneira dinâmica

Animated GIF - Find & Share on GIPHY

Segue o link abaixo do para realizar o download o arquivo

É possível utilizar o site abaixo, onde realizará todos estes cálculos acima.

www.payoffmatrix.com.br

Gostaria de fazer um agradecimento em especial ao Prof. Dr. Marcos Santos pela apresentação passo a passo desta metodologia.

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

E você já conhece o meu novo Curso de Excel EAD?

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "A teoria sempre acaba, mais cedo ou mais tarde, assinada pela experiência" Autor: Albert Eintein

Deixe um comentário

O seu endereço de e-mail não será publicado. Campos obrigatórios são marcados com *