▷ PROMETHEE I e II no Excel

Olá seja bem vindo ao meu mais novo artigo

Neste irei abordar o modelo muticritério de apoio a decisão chamado PROMETHEE (Preference Ranking Method for Enrichment Evaluation) (1982), sendo este um método de fácil entendimento, facilitando o a sua aplicação pelo decisor.

Segue a fonte que ajudou a construir este artigo, obrigado Prof. Dr. Mauricio Uriona Maldonado.

Neste artigo irei demonstrar os cálculos dos métodos I e II, onde na literatura existe diversas evoluções deste modelo, segue abaixo

A família de métodos PROMETHEE se divide em:

• PROMETHEE I – Pré-ordem parcial, problemática de escolha;
• PROMETHEE II – Estabelece uma pré-ordem completa entre as alternativas, podendo ser utilizado também na problemática de escolha;
• PROMETHEE III – Ampliação da noção de indiferença, tratamento probabilístico dos fluxos (preferência intervalar);
• PROMETHEE IV – Pré-ordem completa ou parcial. Problemática de escolha e ordenamento. Destinado as situações em que o conjunto de soluções viáveis é contínuo;
• PROMETHEE V – Nesta implementação, após estabelecer uma ordem completa entre as alternativas (PROMETHEE II), são introduzidas restrições, identificadas no problema, para as alternativas selecionadas; incorpora-se uma filosofia de otimização inteira;
• PROMETHEE VI – Pré-ordem completa ou parcial. Problemática de escolha e ordenamento. Destinado as situações em que o decisor não consegue estabelecer um valor fixo de peso para cada critério;
• PROMETHEE – GAIA – Extensão dos resultados do PROMETHEE, através de um procedimento visual e interativo.

Mas vamos a aplicação prática

Temos a seguinte situação, queremos escolher o melhor sistema para adquirir em uma empresa e conseguimos os seguintes dados.

Sendo que cada critério deve ter um peso, uma escolha de maximização ou minimização, e seus respectivos valores.

Vamos aos passos

1° Passo - Criar a Matriz Normalizada

Será necessário normalizar todos os valores para a realização correta dos cálculos, segue a fórmula iniciando na célula G16.

=SE(G4="";"";SE(G$1="Min";(MÁXIMO(G$4:G$13)-G4)/(MÁXIMO(G$4:G$13)-MÍNIMO(G$4:G$13));(G4-MÍNIMO(G$4:G$13))/(MÁXIMO(G$4:G$13)-MÍNIMO(G$4:G$13))))

ou em inglês

=IF(G4="";"";IF(G$1="Min";(MAX(G$4:G$13)-G4)/(MAX(G$4:G$13)-MIN(G$4:G$13));(G4-MIN(G$4:G$13))/(MAX(G$4:G$13)-MIN(G$4:G$13))))

Com a matriz normalizada criada, será necessário criar a Matriz dos graus de preferência

2° Passo - Criação da Matriz de Preferência

Coeficientes internos iniciando na célula G31

=SE(OU($F31="";G$30="");"";SEERRO(SE($F31=G$30;0;SOMA(ÍNDICE(((
DESLOC($F$16;CORRESP($F31;$F$16:$F$25;0)-1;1;1;$C$10)-
DESLOC($F$16;CORRESP(G$30;$F$16:$F$25;0)-1;1;1;$C$10))>0)*
(DESLOC($F$16;CORRESP($F31;$F$16:$F$25;0)-1;1;1;$C$10)
-DESLOC($F$16;CORRESP(G$30;$F$16:$F$25;0)-1;1;1;$C$10))*
$G$2:$J$2;0)));""))

ou em inglês

=IF(OR($F31="";G$30="");"";IFERROR(IF($F31=G$30;0;SUM(INDEX(((
OFFSET($F$16;MATCH($F31;$F$16:$F$25;0)-1;1;1;$C$10)-
OFFSET($F$16;MATCH(G$30;$F$16:$F$25;0)-1;1;1;$C$10))>0)*
(OFFSET($F$16;MATCH($F31;$F$16:$F$25;0)-1;1;1;$C$10)-
OFFSET($F$16;MATCH(G$30;$F$16:$F$25;0)-1;1;1;$C$10))*
$G$2:$J$2;0)));""))

Cálculo do Phi + | PHOMETHEE I

Segue localizado na coluna S, iniciando na célula S31

=SE(F31="";"";SOMA(G31:P31))

ou em inglês

=IF(F31="";"";SUM(G31:P31))

Cálculo do Phi - | PHOMETHEE I

Segue localizado na linha 28, iniciando na célula G28

=SE(G$30="";"";SOMA(G31:G40))

ou em inglês

=IF(G$30="";"";SUM(G31:G40))

Cálculo do Phi + | PHOMETHEE II

Segue localizado na coluna R, iniciando na célula R31

=SE(F31="";"";MÉDIASE(G31:P31;">0"))

ou em inglês

=IF(F31="";"";AVERAGEIF(G31:P31;">0"))

Cálculo do Phi - | PHOMETHEE II

Segue localizado na linha 27, iniciando na célula G27

=SEERRO(MÉDIASE(G31:G40;">0");"")

ou em inglês

=IFERROR(AVERAGEIF(G31:G40;">0");"")

Após estes cálculos será necessário montar a tabela final deste método

3° Passo - Criação da Tabela Resultado

Vamos as fórmulas

Tabela - PROMETHEE I

Phi+ | Coluna Z

iniciando na célula Z31

=SE(S31="";NÃO.DISP();S31)

ou em inglês

=IF(S31="";NA();S31)

Phi - | Coluna AA

iniciando na célula AA31

=SE(DESLOC($G$28;0;LINS($AA$31:AA31)-1)="";NÃO.DISP();
DESLOC($G$28;0;LINS($AA$31:AA31)-1))

ou em inglês

=IF(OFFSET($G$28;0;ROWS($AA$31:AA31)-1)="";NA();
OFFSET($G$28;0;ROWS($AA$31:AA31)-1))

Segue o gráfico representando o método PROMETHEE I

Tabela - PROMETHEE II

Phi+ | Coluna V

iniciando na célula V31

=R31

Phi - | Coluna W

iniciando na célula W31

=DESLOC($G$27;0;LINS($W$31:W31)-1)

ou em inglês

=OFFSET($G$27;0;ROWS($W$31:W31)-1)

Phi | Coluna X

iniciando na célula X31

=SE(U31="";"";V31-W31)

ou em inglês

=IF(U31="";"";V31-W31)

Ranking | Coluna Y - PROMETHEE II

Iniciando na célula Y31

=SEERRO(ORDEM(X31;$X$31:$X$40);"")

ou em inglês

=IFERROR(RANK(X31;$X$31:$X$40);"")

Nota: Particularmente prefiro o PROMETHEE II, sendo que o mesmo já indica qual é a melhor opção a ser tomada, no exemplo acima a melhor alternativa é a Oracle, já no PROMETHEE I para escolher a melhor alternativa, a barra tem que estar acima de todas, que no exemplo acima fica complexo tomar esta decisão.

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.

E você já conhece o meu novo Curso de Excel EAD?

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do Dia: "Decidir o que não fazer é tão importante quanto decidir o que fazer" Autor: Steven Jobs