Olá seja bem vindo ao meu novo artigo
Neste será demonstrado uma técnica de auxilio a tomada de decisão com multicritérios chamada DEMATEL (Decision Making Trial and Evaluation Laboratory), esta técnica foi desenvolvido por Gabus e Fontela (1972) a fim de analisar um conjunto de critérios ou alternativas, capazes de verificar a influência de um componente sobre o outro sendo que nem sempre é de forma recíproca.
Algumas considerações, as fórmulas estão fixadas com até 50 critérios e 5 escalas de influência, sendo possível aumentar para o limite do Excel. Foi utilizado a função UNIDM / MUNIT esta função retorna a matriz identidade e ela só está disponível no Office 365.
Este método foi apresentado pelo Prof. Dr. Marcos Santos e pelo seu aluno Mestrando Igor Pinheiro de Araújo Costa, muito obrigado senhores.
Mas vamos ao passo a passo.
1° Passo - Definir a escala de Influência
Definir a quantidade de critérios a ser avaliado.
2° Passo - Criação da Matriz D
Nesta etapa será necessário o preenchimento de influências de um critério sobre o outro, sendo a diagonal principal o valor zero.
3° Passo - Criar da Matriz T
Para a criação da Matriz de relacionamento total T = D*(I-D)^-1, sendo que I é a Matriz Identidade.
Segue as fórmulas de todos os elementos da Matriz T iniciando na célula BP4
=SE(E(LINS(O$4:O4)<=$C$12;COLS($O4:O4)<=$C$12);ÍNDICE(MATRIZ.MULT(
(DESLOC($N$3;1;1;$C$12;$C$12)/MÁXIMO(MATRIZ.MULT(DESLOC(
$N$3;1;1;$C$12;$C$12);LIN(INDIRETO("1:"&$C$12))/LIN(INDIRETO(
"1:"&$C$12)))));MATRIZ.INVERSO(MUNIT($C$12)-(DESLOC($N$3;1;1;$C$12;$C$12)
/MÁXIMO(MATRIZ.MULT(DESLOC($N$3;1;1;$C$12;$C$12);LIN(INDIRETO(
"1:"&$C$12))/LIN(INDIRETO("1:"&$C$12)))))));LINS($L$92:L92);
COLS($O$4:O4));"")ou em inglês
=IF(AND(ROWS(O$4:O4)<=$C$12;COLUMNS($O4:O4)<=$C$12);INDEX(MMULT(
(OFFSET($N$3;1;1;$C$12;$C$12)/MAX(MMULT(OFFSET(
$N$3;1;1;$C$12;$C$12);ROW(INDIRECT("1:"&$C$12))/ROW(INDIRECT(
"1:"&$C$12)))));MINVERSE(MUNIT($C$12)-(OFFSET($N$3;1;1;$C$12;$C$12)
/MAX(MMULT(OFFSET($N$3;1;1;$C$12;$C$12);ROW(INDIRECT(
"1:"&$C$12))/ROW(INDIRECT("1:"&$C$12)))))));ROWS($L$92:L92);
COLUMNS($O$4:O4));"")4° Passo - Cálculo dos indices Ci e Ri
Com a matriz criada T podemos obter os coeficientes Ci e Ri
Ci - Soma dos índices por coluna para os critérios - Coluna G
=SE($C$12<LINS($G$4:G4);"";SOMA(DESLOC($BO$3;1;LINS($G$4:G4);$C$12;1)))ou em inglês
=IF($C$12<ROWS($G$4:G4);"";SUM(OFFSET($BO$3;1;ROWS($G$4:G4);$C$12;1)))Ri - Soma dos índices por linha para os critérios - Coluna H
=SE($C$12<LINS($H$4:H4);"";SOMA(DESLOC($BO$3;LINS($H$4:H4);1;1;$C$12)))ou em inglês
=IF($C$12<ROWS($H$4:H4);"";SUM(OFFSET($BO$3;ROWS($H$4:H4);1;1;$C$12)))Ci+Ri - Coluna I
=SE($C$12<LINS($I$4:I4);"";G4+H4)ou em inglês
=IF($C$12<ROWS($I$4:I4);"";G4+H4)Ri-Ci - Coluna J
=SE($C$12<LINS($J$4:J4);"";H4-G4)ou em inglês
=IF($C$12<ROWS($J$4:J4);"";H4-G4)Peso - Coluna K
Este peso não existe nesta técnica, mas realizei a adaptação de outro método chamado WINGS
=SE($C$12<LINS($K$4:K4);"";I4/SOMA($I$4:$I$53))ou em inglês
Após a conclusão dos números segue o gráfico com os critérios
=IF($C$12<ROWS($K$4:K4);"";I4/SUM($I$4:$I$53))
Agora a técnica DEMATEL que auxilia a tomada de decisão com multicritérios de maneira dinâmica
Segue o link abaixo para realizar o download do arquivo
O mesmo foi patenteado sob o Processo de Número BR5120200001828-9, apenas para uso acadêmico e 100% gratuito e uso não comercial
Gostaria de fazer um agradecimento em especial ao Prof. Dr. Marcos Santos e ao Mestrando Igor Pinheiro de Araújo Costa, pela apresentação da técnica.
Também é possível realizar os testes no site abaixo
Espero que tenha gostado desse artigo!
Caso tenha alguma sugestão de outra técnica ou melhoria do conteúdo acima, poste aqui nos comentários.
Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do MS Excel.
E você já conhece o meu novo curso online de Excel?
Abraços a todos e até o próximo artigo!
Fabio BALDINI
Frase do Dia: “Meu trabalho não é facilitar para as pessoas. Meu trabalho é torná-las melhores.” Autor: Steve Jobs
Link permanente