▷ Matriz 9 Box no Excel – Ferramenta para avaliação do desempenho dos colaboradores

Olá pessoal seja bem vindo ao meu novo artigo! Irei descrever neste artigo uma ferramenta que será possível realizar a avaliação de todos os colaboradores. Será considerado nesta técnica diversos fatores de análises, onde a resposta será dada em um dos nove quadrantes deste modelo, que é chamado de Nine Box (Nove Quadros).

Para realizar esse modelo será necessário uma base de dados contendo diversas informações sobre os colaboradores separando em dois eixos principais. Eixo X - Avaliação Comportamental/Potencial e Eixo Y - Desempenho, dentro dos eixos é possível adicionar vários aspectos para resultar um valor final por colaborador. Vamos a base de dados

Eixo X - Comportamental/Desempenho

Talento - Coluna C e D

Neste primeiro critério deverá ser analisado vários fatores (estilo de pensamento, aspectos comportamentais, inteligência emocional, interesses ocupacionais, trabalho sobre pressão) como parte da avaliação, analisando o colaborador em uma determinada posição. Para isso deverá inserir um valor entre 0 e 100 nas células C12 a C16, convertendo-as em escalas Baixo/Médio/Alto, com seus respectivos valores informado nas células C5 a D8, para isso será adicionado a fórmula na célula D12 a D16, segue abaixo:

=SE(C12="";"";ÍNDICE($C$5:$C$7;CORRESP(C12;$D$5:$D$7;1);0))

ou em inglês

=IF(C12="";"";INDEX($C$5:$C$7;MATCH(C12;$D$5:$D$7;1);0))

Neste critério foi considerado o peso no Eixo X de 40%, podendo este ser alterado para cada empresa.

Competência Funcional - Coluna F e G

Neste critério deverá ser analisado os fatores de competência (trabalho em equipe, entrega das metas propostas, acuracidade dos resultados, assiduidade, entre outros) individual ou em equipe, para isto deverá inserir o valor entre 0 e 4 nas células F12 a F16 (poderá utilizar qualquer escala que desejar), informado as suas classificações nas células F5 a G8 e a conversão demonstrada nas células G12 a G16, que segue a fórmula abaixo:

=SE(OU(ÉTEXTO(F12);F12="");"";ÍNDICE($F$5:$F$7;CORRESP(F12;$G$5:$G$7;1);0))

ou em inglês

=IF(OR(ISTEXT(F12);F12="");"";INDEX($F$5:$F$7;MATCH(F12;$G$5:$G$7;1);0))

Neste critério foi considerado o peso no Eixo X de 40%, podendo este ser alterado para cada empresa.

Avaliação 2016 e 2017 - Coluna I, J, K e L

Neste critério deverá inserir as notas dos colaboradores dos anos anteriores do quesito Potencial/Desempenho, para avaliar se o mesmo houve melhoria e evolução entre os anos. Para isso deverá inserir um valor entre 0 e 6. O peso para o Eixo X deste critério foi considerado 20%. Para realizar a fórmula nas células J12 a J16 e L12 a L16, segue a fórmula abaixo:

=SE(OU(ÉTEXTO(I12);I12="");"";ÍNDICE($I$5:$I$7;CORRESP(I12;$J$5:$J$7;1);0))

ou em inglês

=IF(OR(ISTEXT(I12);I12="");"";INDEX($I$5:$I$7;MATCH(I12;$J$5:$J$7;1);0))

Pontuação X - Colunas N e O

Após definidos as pontuações de Talento, Competência Funcional e as Avaliações dos anos anteriores deverá realizar a soma proporcional dos critérios com seus respectivos pesos e definir o resultado do Eixo X, que segue as fórmulas abaixo:

Pontuação do Eixo X - Células N12 a N16

=SEERRO((C12/$D$8*$D$10+(F12/$G$8)*$G$10+(MÉDIA(K12;I12)/$J$8)*$J$10)*100;"")

ou em inglês

=IFERROR((C12/$D$8*$D$10+(F12/$G$8)*$G$10+(AVERAGE(K12;I12)/$J$8)*$J$10)*100;"")

Resultado da Avaliação do Eixo X - Células O12 a O16

=SE(OU(ÉTEXTO(N12);N12="");"";ÍNDICE($N$5:$N$7;CORRESP(N12;$O$5:$O$7;1);0))

ou em inglês

=IF(OR(ISTEXT(N12);N12="");"";INDEX($N$5:$N$7;MATCH(N12;$O$5:$O$7;1);0))

Eixo Y - Desempenho

Meta 2016 e 2017 - Colunas Q, R, S e T

Neste eixo deverá considerar os valores dos resultados metas individuais e coletivas informados nos anos anteriores nas células Q12 a Q16 e S12 a S16. Para este critério deverá inserir valores entre 0% a 100%. As conversões serão informadas nas células R12 a R16 e T12 a T16 que segue a fórmula abaixo

=SE(OU(ÉTEXTO(Q12);Q12="");"";ÍNDICE($Q$5:$Q$7;CORRESP(Q12;$R$5:$R$7;1);0))

ou em inglês

=IF(OR(ISTEXT(Q12);Q12="");"";INDEX($Q$5:$Q$7;MATCH(Q12;$R$5:$R$7;1);0))

Neste exemplo foi considerado para o ano de 2016 o peso de 40% e para o ano de 2017 o peso de 60%.

Pontuação Y - Coluna V e W

Com os valores inseridos das metas dos anos anteriores, utilizaremos a mesma lógica da pontuação do Eixo X, realizaremos a soma proporcional informada nas células V12 a V16, que segue abaixo

=SEERRO(((Q12*$R$10+S12*$T$10)*100);"")

ou em inglês

=IFERROR(((Q12*$R$10+S12*$T$10)*100);"")

Com os valores calculados, deverá associar os critérios conforme a fórmula abaixo, informada nas células W12 a W16

=SE(OU(ÉTEXTO(S12);S12="");"";ÍNDICE($V$5:$V$7;CORRESP((Q12*$R$10+S12*$T$10);$W$5:$W$7;1);0))

ou em inglês

=IF(OR(ISTEXT(S12);S12="");"";INDEX($V$5:$V$7;MATCH((Q12*$R$10+S12*$T$10);$W$5:$W$7;1);0))

Cálculo das Conversões dos Eixos X e Y

Após o cálculo dos Eixos X (Coluna N) e o Eixo Y (Coluna V), ambos eixos estão em uma classificação entre 0 e 100, mas estes valores não são suficientes para colocar no gráfico do MS Excel. Será necessário realizar uma conversão da escala atual em uma escala onde possa ser inserido e interpretado pelo MS Excel, onde será interpolado com os valores informados na imagem abaixo, resultando nos Eixo convertido X e Eixo convertido Y.

Segue a fórmula da Conversão da Pontuação do Eixo Y - Célula Y12 a Y16

=SE(V12=0;0;((((Q12*$R$10+S12*$T$10)*100)-ÍNDICE($AC$5:$AC$8;CORRESP(V12;$AC$5:$AC$8;-1)+1;0))/(ÍNDICE($AC$5:$AC$8;CORRESP(V12;$AC$5:$AC$8;-1);0)-ÍNDICE($AC$5:$AC$8;CORRESP(V12;$AC$5:$AC$8;-1)+1;0)))*(ÍNDICE($AD$5:$AD$8;CORRESP(V12;$AC$5:$AC$8;-1);0)-ÍNDICE($AD$5:$AD$8;CORRESP(V12;$AC$5:$AC$8;-1)+1;0))+ÍNDICE($AD$5:$AD$8;CORRESP(V12;$AC$5:$AC$8;-1)+1;0))

ou em inglês

=IF(V12=0;0;((((Q12*$R$10+S12*$T$10)*100)-INDEX($AC$5:$AC$8;MATCH(V12;$AC$5:$AC$8;-1)+1;0))/(INDEX($AC$5:$AC$8;MATCH(V12;$AC$5:$AC$8;-1);0)-INDEX($AC$5:$AC$8;MATCH(V12;$AC$5:$AC$8;-1)+1;0)))*(INDEX($AD$5:$AD$8;MATCH(V12;$AC$5:$AC$8;-1);0)-INDEX($AD$5:$AD$8;MATCH(V12;$AC$5:$AC$8;-1)+1;0))+INDEX($AD$5:$AD$8;MATCH(V12;$AC$5:$AC$8;-1)+1;0))

Segue a fórmula da Conversão da Pontuação do Eixo X - Célula Z12 a Z16

=SE(N12=100;$AH$4;((N12-ÍNDICE($AE$3:$AH$3;0;CORRESP(N12;$AE$3:$AH$3;1)+1))/(ÍNDICE($AE$3:$AG$3;0;CORRESP(N12;$AE$3:$AH$3;1))-ÍNDICE($AE$3:$AH$3;0;CORRESP(N12;$AE$3:$AH$3;1)+1)))*(ÍNDICE($AE$4:$AH$4;0;CORRESP(N12;$AE$3:$AH$3;1))-ÍNDICE($AE$4:$AH$4;0;CORRESP(N12;$AE$3:$AH$3;1)+1))+ÍNDICE($AE$4:$AH$4;0;CORRESP(N12;$AE$3:$AH$3;1)+1))

ou em inglês

=IF(N12=100;$AH$4;((N12-INDEX($AE$3:$AH$3;0;MATCH(N12;$AE$3:$AH$3;1)+1))/(INDEX($AE$3:$AG$3;0;MATCH(N12;$AE$3:$AH$3;1))-INDEX($AE$3:$AH$3;0;MATCH(N12;$AE$3:$AH$3;1)+1)))*(INDEX($AE$4:$AH$4;0;MATCH(N12;$AE$3:$AH$3;1))-INDEX($AE$4:$AH$4;0;MATCH(N12;$AE$3:$AH$3;1)+1))+INDEX($AE$4:$AH$4;0;MATCH(N12;$AE$3:$AH$3;1)+1))

Por último, segue a fórmula do Resultado das combinações dos Eixos X e Y para os 9 quadrantes (9 box) - Célula AA12 a AA16

=DESLOC($AD$4;CORRESP(Y12;$AD$5:$AD$7;-1);CORRESP(Z12;$AE$4:$AG$4;1))

ou em inglês

=OFFSET($AD$4;MATCH(Y12;$AD$5:$AD$7;-1);MATCH(Z12;$AE$4:$AG$4;1))

Espero que tenha gostado desse artigo!

Caso tenha alguma sugestão deste modelo, poste aqui nos comentários.

Se gostou, curta e compartilhe este artigo para que todos saibam o que é possível fazer dentro do Excel.

E ja conhece o meu novo curso online de Excel?

Abraços a todos e até o próximo artigo!

Fabio BALDINI

Frase do dia:"Se quer plantar para poucos dias, plante flores. Se quer plantar por muitos anos, plante uma árvore, se quer plantar para a eternidade, plante ideias." Provérbio Oriental